doc/meson.build: fix manual install dir
[ncmpc-debian.git] / doc / meson.build
1 sphinx = find_program('sphinx-build', required: get_option('documentation'))
2 if not sphinx.found()
3   subdir_done()
4 endif
5
6 if get_option('html_manual')
7   sphinx_output = custom_target(
8     'HTML documentation',
9     output: 'html',
10     input: ['index.rst', 'conf.py'],
11     command: [sphinx, '-q', '-b', 'html', '-d', '@OUTDIR@/html_doctrees', meson.current_source_dir(), '@OUTPUT@'],
12     build_by_default: true,
13     install: true,
14     install_dir: join_paths(get_option('datadir'), 'doc', meson.project_name()),
15   )
16
17   custom_target(
18     'upload',
19     input: sphinx_output,
20     output: 'upload',
21     build_always_stale: true,
22     command: [
23       'rsync', '-vpruz', '--delete', '@INPUT@',
24       'www.musicpd.org:/var/www/mpd/doc/ncmpc/',
25       '--chmod=a+rX',
26     ],
27   )
28 endif
29
30 if get_option('manual')
31   custom_target(
32     'Manpage documentation',
33     output: 'man1',
34     input: ['index.rst', 'conf.py'],
35     command: [sphinx, '-q', '-b', 'man', '-d', '@OUTDIR@/man_doctrees', meson.current_source_dir(), '@OUTPUT@'],
36     build_by_default: true,
37     install: true,
38     install_dir: get_option('mandir'),
39   )
40 endif