ListWindow: convert list_window_callback_fn_t to an abstract class
[ncmpc-debian.git] / meson.build
1 project('ncmpc', 'cpp',
2   version: '0.30',
3   default_options: [
4     'cpp_std=c++14'
5   ],
6   license: 'GPLv2+',
7 )
8
9 cc = meson.get_compiler('cpp')
10
11 conf = configuration_data()
12 conf.set_quoted('PACKAGE', meson.project_name())
13 conf.set_quoted('VERSION', meson.project_version())
14 conf.set_quoted('SYSCONFDIR', join_paths(get_option('prefix'), get_option('sysconfdir')))
15 conf.set_quoted('LOCALE_DIR', join_paths(get_option('prefix'), get_option('localedir')))
16
17 mini = get_option('mini')
18 conf.set('NCMPC_MINI', mini)
19
20 enable_locale = get_option('locale')
21 if enable_locale == 'false' or mini
22   enable_locale = false
23 elif cc.has_header('locale.h')
24   enable_locale = true
25 elif enable_locale == 'auto'
26   enable_locale = false
27 else
28   error('locale.h not found')
29 endif
30 conf.set('ENABLE_LOCALE', enable_locale)
31
32 enable_nls = get_option('nls')
33 if enable_nls == 'false' or mini
34   enable_nls = false
35 elif cc.has_header('libintl.h')
36   enable_nls = true
37 elif enable_nls == 'auto'
38   enable_nls = false
39 else
40   error('libintl.h not found')
41 endif
42 conf.set('ENABLE_NLS', enable_nls)
43 if enable_nls
44   conf.set_quoted('GETTEXT_PACKAGE', meson.project_name())
45   subdir('po')
46 endif
47
48 if get_option('tcp')
49   conf.set('ENABLE_TCP', true)
50   conf.set('HAVE_GETADDRINFO', cc.has_function('getaddrinfo'))
51 endif
52
53 async_connect = get_option('async_connect')
54 conf.set('ENABLE_ASYNC_CONNECT', async_connect)
55
56 conf.set('ENABLE_MULTIBYTE', get_option('multibyte'))
57
58 curses = get_option('curses')
59 if curses == 'ncursesw'
60   curses_dep = dependency('ncursesw')
61 elif curses == 'ncurses'
62   curses_dep = dependency('ncurses')
63 else
64   curses_dep = dependency('ncursesw', required: false)
65   if curses_dep.found()
66     curses = 'ncursesw'
67   else
68     curses_dep = dependency('ncurses', required: false)
69
70     if curses_dep.found()
71       curses = 'ncurses'
72     else
73       curses_dep = cc.find_library('ncursesw', required: false)
74       if not curses_dep.found()
75         curses_dep = cc.find_library('ncurses')
76       endif
77
78       # TODO: find other curses implementation (pdcurses?)
79     endif
80   endif
81 endif
82
83 if curses == 'ncursesw'
84   conf.set('HAVE_NCURSESW', true)
85   curses_enhanced = true
86   curses_color = true
87   if cc.has_header('ncursesw/curses.h', dependencies: curses_dep)
88     conf.set('HAVE_NCURSESW_CURSES_H', true)
89   elif cc.has_header('ncursesw.h', dependencies: curses_dep)
90     conf.set('HAVE_NCURSESW_H', true)
91   else
92     error('No ncursesw header found')
93   endif
94 elif curses == 'ncurses'
95   conf.set('HAVE_NCURSES', true)
96   curses_enhanced = true
97   curses_color = true
98   if cc.has_header('ncurses/curses.h', dependencies: curses_dep)
99     conf.set('HAVE_NCURSES_CURSES_H', true)
100   elif cc.has_header('ncurses.h', dependencies: curses_dep)
101     conf.set('HAVE_NCURSES_H', true)
102   else
103     error('No ncurses header found')
104   endif
105 else
106   if cc.has_header('curses.h', dependencies: curses_dep)
107     conf.set('HAVE_CURSES_H', true)
108
109     # TODO: test this with pdcurses
110     curses_enhanced = cc.has_header_symbol('curses.h', '_XOPEN_CURSES', dependencies: curses_dep)
111     curses_color = curses_enhanced or cc.has_header_symbol('curses.h', 'COLOR_PAIR', dependencies: curses_dep)
112   else
113     error('No curses header found')
114   endif
115 endif
116 conf.set('HAVE_CURSES_ENHANCED', curses_enhanced)
117
118 enable_mouse = get_option('mouse')
119 if enable_mouse == 'false'
120   enable_mouse = false
121 elif cc.has_function('getmouse', dependencies: curses_dep)
122   enable_mouse = true
123 elif enable_mouse == 'auto'
124   enable_mouse = false
125 else
126   error('getmouse() not available')
127 endif
128 conf.set('HAVE_GETMOUSE', enable_mouse)
129
130 enable_lirc = get_option('lirc')
131 if enable_lirc == 'false'
132   enable_lirc = false
133   lirc_dep = []
134 else
135   lirc_dep = dependency('lirc', required: false)
136   if not lirc_dep.found()
137     lirc_dep = dependency('liblircclient0', required: false)
138   endif
139
140   if lirc_dep.found()
141     enable_lirc = true
142   elif enable_lirc == 'auto'
143     enable_lirc = false
144   else
145     error('liblirc not found')
146   endif
147 endif
148 conf.set('ENABLE_LIRC', enable_lirc)
149
150 conf.set('ENABLE_COLORS', curses_color)
151
152 common_cflags = [
153   # for getaddrinfo() and sigaction() with glibc
154   '-D_GNU_SOURCE',
155 ]
156
157 test_cflags = [
158   '-Wall',
159   '-Wextra',
160   '-Wno-deprecated-declarations',
161   '-Wshadow',
162   '-Wpointer-arith',
163   '-Wcast-qual',
164   '-Wcast-align',
165   '-Wwrite-strings',
166   '-Wmissing-declarations', '-Wmissing-noreturn', '-Wmissing-format-attribute',
167   '-Wredundant-decls', '-Wundef',
168   '-Wno-non-virtual-dtor',
169   '-fvisibility=hidden',
170   '-fno-exceptions',
171   '-fno-rtti',
172 ]
173
174 test_ldflags = [
175 ]
176
177 if get_option('buildtype') != 'debug'
178   test_cflags += [
179     '-ffunction-sections',
180     '-fdata-sections',
181   ]
182   test_ldflags += [
183     '-Wl,--gc-sections',
184   ]
185 endif
186
187 foreach f: test_cflags
188   if cc.has_argument(f)
189     common_cflags += [ f ]
190   endif
191 endforeach
192
193 add_global_arguments(common_cflags, language: 'cpp')
194
195 foreach f: test_ldflags
196   if cc.has_argument(f)
197     add_global_link_arguments(f, language: 'cpp')
198   endif
199 endforeach
200
201 glib_dep = dependency('glib-2.0', version: '>= 2.30')
202 libmpdclient_dep = dependency('libmpdclient', version: '>= 2.9')
203
204 inc = include_directories(
205   'src',
206
207   # for the generated config.h
208   '.',
209 )
210
211 sources = []
212
213 need_screen_text = false
214 need_plugin_library = false
215
216 if host_machine.system() != 'windows'
217   sources += [
218     'src/signals.cxx',
219   ]
220 endif
221
222 if not mini
223   sources += [
224     'src/db_completion.cxx',
225     'src/xterm_title.cxx',
226     'src/BasicMarquee.cxx',
227     'src/hscroll.cxx',
228     'src/match.cxx',
229     'src/conf.cxx',
230   ]
231 endif
232
233 if async_connect
234   sources += [
235     'src/net/socket.cxx',
236     'src/net/resolver.cxx',
237     'src/net/async_connect.cxx',
238     'src/net/async_rconnect.cxx',
239     'src/aconnect.cxx',
240   ]
241 endif
242
243 if enable_lirc
244   sources += [
245     'src/lirc.cxx',
246   ]
247 endif
248
249 enable_help_screen = get_option('help_screen') and not mini
250 conf.set('ENABLE_HELP_SCREEN', enable_help_screen)
251 if enable_help_screen
252   sources += ['src/screen_help.cxx']
253 endif
254
255 enable_artist_screen = get_option('artist_screen') and not mini
256 conf.set('ENABLE_ARTIST_SCREEN', enable_artist_screen)
257 if enable_artist_screen
258   sources += [
259     'src/screen_artist.cxx',
260     'src/ArtistListPage.cxx',
261     'src/AlbumListPage.cxx',
262   ]
263 endif
264
265 enable_search_screen = get_option('search_screen') and not mini
266 conf.set('ENABLE_SEARCH_SCREEN', enable_search_screen)
267 if enable_search_screen
268   sources += ['src/screen_search.cxx']
269 endif
270
271 enable_song_screen = get_option('song_screen') and not mini
272 conf.set('ENABLE_SONG_SCREEN', enable_song_screen)
273 if enable_song_screen
274   sources += ['src/screen_song.cxx']
275 endif
276
277 enable_keydef_screen = get_option('key_screen') and not mini
278 conf.set('ENABLE_KEYDEF_SCREEN', enable_keydef_screen)
279 if enable_keydef_screen
280   sources += ['src/screen_keydef.cxx']
281 endif
282
283 enable_lyrics_screen = get_option('lyrics_screen') and not mini
284 conf.set('ENABLE_LYRICS_SCREEN', enable_lyrics_screen)
285 if enable_lyrics_screen
286   sources += ['src/screen_lyrics.cxx', 'src/lyrics.cxx']
287
288   lyrics_plugin_dir = get_option('lyrics_plugin_dir')
289   if lyrics_plugin_dir == ''
290     lyrics_plugin_dir = join_paths(get_option('prefix'), get_option('libdir'), meson.project_name(), 'lyrics')
291   endif
292
293   conf.set_quoted('LYRICS_PLUGIN_DIR', lyrics_plugin_dir)
294   install_data(
295     'lyrics/10-hd.sh',
296     'lyrics/20-lyricwiki.rb',
297     install_dir: lyrics_plugin_dir)
298
299   need_screen_text = true
300   need_plugin_library = true
301 endif
302
303 enable_outputs_screen = get_option('outputs_screen') and not mini
304 conf.set('ENABLE_OUTPUTS_SCREEN', enable_outputs_screen)
305 if enable_outputs_screen
306   sources += ['src/screen_outputs.cxx']
307 endif
308
309 enable_chat_screen = get_option('chat_screen') and not mini
310 conf.set('ENABLE_CHAT_SCREEN', enable_chat_screen)
311 if enable_chat_screen
312   sources += ['src/screen_chat.cxx']
313   need_screen_text = true
314 endif
315
316 if need_screen_text
317   sources += ['src/TextPage.cxx']
318 endif
319
320 if need_plugin_library
321   if host_machine.system() == 'windows'
322     error('Plugins not yet compatible with Windows')
323   endif
324
325   sources += ['src/plugin.cxx']
326 endif
327
328 if host_machine.system() == 'windows'
329   subdir('src/win')
330 endif
331
332 ncmpc = executable('ncmpc',
333   'src/Main.cxx',
334   'src/gidle.cxx',
335   'src/mpdclient.cxx',
336   'src/callbacks.cxx',
337   'src/Queue.cxx',
338   'src/filelist.cxx',
339   'src/options.cxx',
340   'src/command.cxx',
341   'src/keyboard.cxx',
342   'src/ncu.cxx',
343   'src/player_command.cxx',
344   'src/TitleBar.cxx',
345   'src/ProgressBar.cxx',
346   'src/StatusBar.cxx',
347   'src/screen.cxx',
348   'src/screen_init.cxx',
349   'src/screen_paint.cxx',
350   'src/screen_utils.cxx',
351   'src/screen_status.cxx',
352   'src/screen_list.cxx',
353   'src/screen_find.cxx',
354   'src/screen_client.cxx',
355   'src/screen_queue.cxx',
356   'src/screen_browser.cxx',
357   'src/screen_file.cxx',
358   'src/ProxyPage.cxx',
359   'src/ListWindow.cxx',
360   'src/TextListRenderer.cxx',
361   'src/save_playlist.cxx',
362   'src/song_paint.cxx',
363   'src/colors.cxx',
364   'src/charset.cxx',
365   'src/wreadln.cxx',
366   'src/Completion.cxx',
367   'src/strfsong.cxx',
368   'src/time_format.cxx',
369   sources,
370   include_directories: inc,
371   dependencies: [
372     glib_dep,
373     curses_dep,
374     lirc_dep,
375     libmpdclient_dep,
376   ],
377   install: true
378 )
379
380 configure_file(output: 'config.h', configuration: conf)
381
382 docdir = join_paths(get_option('datadir'), 'doc', meson.project_name())
383 install_data('AUTHORS', 'COPYING', 'NEWS', 'README.rst',
384   'doc/config.sample',
385   'doc/keys.sample',
386   'doc/ncmpc.lirc',
387   install_dir: docdir)
388
389 if not mini
390   subdir('test')
391 endif
392
393 subdir('doc')