meson.build

   1 project('ncmpc', 'cpp',
   2   version: '0.30',
   3   default_options: [
   4     'cpp_std=c++14'
   5   ],
   6   license: 'GPLv2+',
   7 )
   8
   9 cc = meson.get_compiler('cpp')
  10
  11 conf = configuration_data()
  12 conf.set_quoted('PACKAGE', meson.project_name())
  13 conf.set_quoted('VERSION', meson.project_version())
  14 conf.set_quoted('SYSCONFDIR', join_paths(get_option('prefix'), get_option('sysconfdir')))
  15 conf.set_quoted('LOCALE_DIR', join_paths(get_option('prefix'), get_option('localedir')))
  16
  17 mini = get_option('mini')
  18 conf.set('NCMPC_MINI', mini)
  19
  20 enable_locale = get_option('locale')
  21 if enable_locale == 'false' or mini
  22   enable_locale = false
  23 elif cc.has_header('locale.h')
  24   enable_locale = true
  25 elif enable_locale == 'auto'
  26   enable_locale = false
  27 else
  28   error('locale.h not found')
  29 endif
  30 conf.set('ENABLE_LOCALE', enable_locale)
  31
  32 enable_nls = get_option('nls')
  33 if enable_nls == 'false' or mini
  34   enable_nls = false
  35 elif cc.has_header('libintl.h')
  36   enable_nls = true
  37 elif enable_nls == 'auto'
  38   enable_nls = false
  39 else
  40   error('libintl.h not found')
  41 endif
  42 conf.set('ENABLE_NLS', enable_nls)
  43 if enable_nls
  44   conf.set_quoted('GETTEXT_PACKAGE', meson.project_name())
  45   subdir('po')
  46 endif
  47
  48 if get_option('tcp')
  49   conf.set('ENABLE_TCP', true)
  50   conf.set('HAVE_GETADDRINFO', cc.has_function('getaddrinfo'))
  51 endif
  52
  53 async_connect = get_option('async_connect')
  54 conf.set('ENABLE_ASYNC_CONNECT', async_connect)
  55
  56 conf.set('ENABLE_MULTIBYTE', get_option('multibyte'))
  57
  58 curses = get_option('curses')
  59 if curses == 'ncursesw'
  60   curses_dep = dependency('ncursesw')
  61 elif curses == 'ncurses'
  62   curses_dep = dependency('ncurses')
  63 else
  64   curses_dep = dependency('ncursesw', required: false)
  65   if curses_dep.found()
  66     curses = 'ncursesw'
  67   else
  68     curses_dep = dependency('ncurses', required: false)
  69
  70     if curses_dep.found()
  71       curses = 'ncurses'
  72     else
  73       curses_dep = cc.find_library('ncursesw', required: false)
  74       if not curses_dep.found()
  75         curses_dep = cc.find_library('ncurses')
  76       endif
  77
  78       # TODO: find other curses implementation (pdcurses?)
  79     endif
  80   endif
  81 endif
  82
  83 if curses == 'ncursesw'
  84   conf.set('HAVE_NCURSESW', true)
  85   curses_enhanced = true
  86   curses_color = true
  87   if cc.has_header('ncursesw/curses.h', dependencies: curses_dep)
  88     conf.set('HAVE_NCURSESW_CURSES_H', true)
  89   elif cc.has_header('ncursesw.h', dependencies: curses_dep)
  90     conf.set('HAVE_NCURSESW_H', true)
  91   else
  92     error('No ncursesw header found')
  93   endif
  94 elif curses == 'ncurses'
  95   conf.set('HAVE_NCURSES', true)
  96   curses_enhanced = true
  97   curses_color = true
  98   if cc.has_header('ncurses/curses.h', dependencies: curses_dep)
  99     conf.set('HAVE_NCURSES_CURSES_H', true)
 100   elif cc.has_header('ncurses.h', dependencies: curses_dep)
 101     conf.set('HAVE_NCURSES_H', true)
 102   else
 103     error('No ncurses header found')
 104   endif
 105 else
 106   if cc.has_header('curses.h', dependencies: curses_dep)
 107     conf.set('HAVE_CURSES_H', true)
 108
 109     # TODO: test this with pdcurses
 110     curses_enhanced = cc.has_header_symbol('curses.h', '_XOPEN_CURSES', dependencies: curses_dep)
 111     curses_color = curses_enhanced or cc.has_header_symbol('curses.h', 'COLOR_PAIR', dependencies: curses_dep)
 112   else
 113     error('No curses header found')
 114   endif
 115 endif
 116 conf.set('HAVE_CURSES_ENHANCED', curses_enhanced)
 117
 118 enable_mouse = get_option('mouse')
 119 if enable_mouse == 'false'
 120   enable_mouse = false
 121 elif cc.has_function('getmouse', dependencies: curses_dep)
 122   enable_mouse = true
 123 elif enable_mouse == 'auto'
 124   enable_mouse = false
 125 else
 126   error('getmouse() not available')
 127 endif
 128 conf.set('HAVE_GETMOUSE', enable_mouse)
 129
 130 enable_lirc = get_option('lirc')
 131 if enable_lirc == 'false'
 132   enable_lirc = false
 133   lirc_dep = []
 134 else
 135   lirc_dep = dependency('lirc', required: false)
 136   if not lirc_dep.found()
 137     lirc_dep = dependency('liblircclient0', required: false)
 138   endif
 139
 140   if lirc_dep.found()
 141     enable_lirc = true
 142   elif enable_lirc == 'auto'
 143     enable_lirc = false
 144   else
 145     error('liblirc not found')
 146   endif
 147 endif
 148 conf.set('ENABLE_LIRC', enable_lirc)
 149
 150 conf.set('ENABLE_COLORS', curses_color)
 151
 152 common_cflags = [
 153   # for getaddrinfo() and sigaction() with glibc
 154   '-D_GNU_SOURCE',
 155 ]
 156
 157 test_cflags = [
 158   '-Wall',
 159   '-Wextra',
 160   '-Wno-deprecated-declarations',
 161   '-Wshadow',
 162   '-Wpointer-arith',
 163   '-Wcast-qual',
 164   '-Wcast-align',
 165   '-Wwrite-strings',
 166   '-Wmissing-declarations', '-Wmissing-noreturn', '-Wmissing-format-attribute',
 167   '-Wredundant-decls', '-Wundef',
 168   '-fvisibility=hidden',
 169   '-fno-exceptions',
 170   '-fno-rtti',
 171 ]
 172
 173 test_ldflags = [
 174 ]
 175
 176 if get_option('buildtype') != 'debug'
 177   test_cflags += [
 178     '-ffunction-sections',
 179     '-fdata-sections',
 180   ]
 181   test_ldflags += [
 182     '-Wl,--gc-sections',
 183   ]
 184 endif
 185
 186 foreach f: test_cflags
 187   if cc.has_argument(f)
 188     common_cflags += [ f ]
 189   endif
 190 endforeach
 191
 192 add_global_arguments(common_cflags, language: 'cpp')
 193
 194 foreach f: test_ldflags
 195   if cc.has_argument(f)
 196     add_global_link_arguments(f, language: 'cpp')
 197   endif
 198 endforeach
 199
 200 glib_dep = dependency('glib-2.0', version: '>= 2.30')
 201 libmpdclient_dep = dependency('libmpdclient', version: '>= 2.9')
 202
 203 inc = include_directories(
 204   'src',
 205
 206   # for the generated config.h
 207   '.',
 208 )
 209
 210 sources = []
 211
 212 need_screen_text = false
 213 need_plugin_library = false
 214
 215 if host_machine.system() != 'windows'
 216   sources += [
 217     'src/signals.cxx',
 218   ]
 219 endif
 220
 221 if not mini
 222   sources += [
 223     'src/db_completion.cxx',
 224     'src/xterm_title.cxx',
 225     'src/BasicMarquee.cxx',
 226     'src/hscroll.cxx',
 227     'src/match.cxx',
 228     'src/conf.cxx',
 229   ]
 230 endif
 231
 232 if async_connect
 233   sources += [
 234     'src/net/socket.cxx',
 235     'src/net/resolver.cxx',
 236     'src/net/async_connect.cxx',
 237     'src/net/async_rconnect.cxx',
 238     'src/aconnect.cxx',
 239   ]
 240 endif
 241
 242 if enable_lirc
 243   sources += [
 244     'src/lirc.cxx',
 245   ]
 246 endif
 247
 248 enable_help_screen = get_option('help_screen') and not mini
 249 conf.set('ENABLE_HELP_SCREEN', enable_help_screen)
 250 if enable_help_screen
 251   sources += ['src/screen_help.cxx']
 252 endif
 253
 254 enable_artist_screen = get_option('artist_screen') and not mini
 255 conf.set('ENABLE_ARTIST_SCREEN', enable_artist_screen)
 256 if enable_artist_screen
 257   sources += [
 258     'src/screen_artist.cxx',
 259     'src/ArtistListPage.cxx',
 260     'src/AlbumListPage.cxx',
 261   ]
 262 endif
 263
 264 enable_search_screen = get_option('search_screen') and not mini
 265 conf.set('ENABLE_SEARCH_SCREEN', enable_search_screen)
 266 if enable_search_screen
 267   sources += ['src/screen_search.cxx']
 268 endif
 269
 270 enable_song_screen = get_option('song_screen') and not mini
 271 conf.set('ENABLE_SONG_SCREEN', enable_song_screen)
 272 if enable_song_screen
 273   sources += ['src/screen_song.cxx']
 274 endif
 275
 276 enable_keydef_screen = get_option('key_screen') and not mini
 277 conf.set('ENABLE_KEYDEF_SCREEN', enable_keydef_screen)
 278 if enable_keydef_screen
 279   sources += ['src/screen_keydef.cxx']
 280 endif
 281
 282 enable_lyrics_screen = get_option('lyrics_screen') and not mini
 283 conf.set('ENABLE_LYRICS_SCREEN', enable_lyrics_screen)
 284 if enable_lyrics_screen
 285   sources += ['src/screen_lyrics.cxx', 'src/lyrics.cxx']
 286
 287   lyrics_plugin_dir = get_option('lyrics_plugin_dir')
 288   if lyrics_plugin_dir == ''
 289     lyrics_plugin_dir = join_paths(get_option('prefix'), get_option('libdir'), meson.project_name(), 'lyrics')
 290   endif
 291
 292   conf.set_quoted('LYRICS_PLUGIN_DIR', lyrics_plugin_dir)
 293   install_data(
 294     'lyrics/10-hd.sh',
 295     'lyrics/20-lyricwiki.rb',
 296     install_dir: lyrics_plugin_dir)
 297
 298   need_screen_text = true
 299   need_plugin_library = true
 300 endif
 301
 302 enable_outputs_screen = get_option('outputs_screen') and not mini
 303 conf.set('ENABLE_OUTPUTS_SCREEN', enable_outputs_screen)
 304 if enable_outputs_screen
 305   sources += ['src/screen_outputs.cxx']
 306 endif
 307
 308 enable_chat_screen = get_option('chat_screen') and not mini
 309 conf.set('ENABLE_CHAT_SCREEN', enable_chat_screen)
 310 if enable_chat_screen
 311   sources += ['src/screen_chat.cxx']
 312   need_screen_text = true
 313 endif
 314
 315 if need_screen_text
 316   sources += ['src/TextPage.cxx']
 317 endif
 318
 319 if need_plugin_library
 320   if host_machine.system() == 'windows'
 321     error('Plugins not yet compatible with Windows')
 322   endif
 323
 324   sources += ['src/plugin.cxx']
 325 endif
 326
 327 if host_machine.system() == 'windows'
 328   subdir('src/win')
 329 endif
 330
 331 ncmpc = executable('ncmpc',
 332   'src/Main.cxx',
 333   'src/gidle.cxx',
 334   'src/mpdclient.cxx',
 335   'src/callbacks.cxx',
 336   'src/Queue.cxx',
 337   'src/filelist.cxx',
 338   'src/options.cxx',
 339   'src/command.cxx',
 340   'src/keyboard.cxx',
 341   'src/ncu.cxx',
 342   'src/player_command.cxx',
 343   'src/TitleBar.cxx',
 344   'src/ProgressBar.cxx',
 345   'src/StatusBar.cxx',
 346   'src/screen.cxx',
 347   'src/screen_init.cxx',
 348   'src/screen_paint.cxx',
 349   'src/screen_utils.cxx',
 350   'src/screen_status.cxx',
 351   'src/screen_list.cxx',
 352   'src/screen_find.cxx',
 353   'src/screen_client.cxx',
 354   'src/screen_queue.cxx',
 355   'src/screen_browser.cxx',
 356   'src/screen_file.cxx',
 357   'src/ProxyPage.cxx',
 358   'src/ListWindow.cxx',
 359   'src/save_playlist.cxx',
 360   'src/song_paint.cxx',
 361   'src/colors.cxx',
 362   'src/charset.cxx',
 363   'src/wreadln.cxx',
 364   'src/strfsong.cxx',
 365   'src/time_format.cxx',
 366   'src/utils.cxx',
 367   sources,
 368   include_directories: inc,
 369   dependencies: [
 370     glib_dep,
 371     curses_dep,
 372     lirc_dep,
 373     libmpdclient_dep,
 374   ],
 375   install: true
 376 )
 377
 378 configure_file(output: 'config.h', configuration: conf)
 379
 380 docdir = join_paths(get_option('datadir'), 'doc', meson.project_name())
 381 install_data('AUTHORS', 'COPYING', 'NEWS', 'README.rst',
 382   'doc/config.sample',
 383   'doc/keys.sample',
 384   'doc/ncmpc.lirc',
 385   install_dir: docdir)
 386
 387 if not mini
 388   subdir('test')
 389 endif
 390
 391 subdir('doc')